pSPSS: pSPSS.fr

File pSPSS.fr, 27.9 KB (added by Jan Hajer, 3 years ago)
Line 
1(* This is the FeynRules model file for the phenomenological Symmetry Protected Seesaw with light Dirac neutrinos*)
2(* The Dirac type light neutrinos allow to enforce lepton number also in processes involving light neutrinos*)
3(* Based on the SM model file *)
4
5M$ModelName = "pSPSS";
6
7M$Information = {
8 Version -> "1.2",
9 Authors -> {"S. Antusch", "J. Hajer", "B. Oliveira", "J. Rosskopp"},
10 Institutions -> {"University of Lisbon", "University of Basel"},
11 Emails -> {"stefan.antusch@unibas.ch", "jan.hajer@tecnico.ulisboa.pt", "b.m.silva.oliveira@tecnico.ulisboa.pt", "johannes.rosskopp@unibas.ch"},
12 References -> {"S. Antusch, J. Hajer, J. Rosskopp, Simulating heavy neutrino-antineutrino oscillations at colliders (2022)", "S. Antusch, J. Hajer, B. Oliveira, Heavy neutrino-antineutrino oscillations at the FCC-ee (2023)"},
13 URLs -> "https://feynrules.irmp.ucl.ac.be/wiki/pSPSS",
14 Date -> "24.01.2024"
15};
16
17(* Change log. *)
18(* v1.0: First published version. *)
19(* v1.1: Light neutrinos are now Dirac in order to simulate neutral initial states. *)
20(* v1.2: Correct light neutrino mass normalisation. *)
21
22(* Choose whether Feynman gauge is desired. If set to False, unitary gauge is assumed. *)
23(* Feynman gauge is especially useful for CalcHEP/CompHEP where the calculation is 10-100 times faster. *)
24(* Feynman gauge is not supported in MadGraph and Sherpa. *)
25
26FeynmanGauge = False;
27
28(* NLO Variables *)
29
30FR$LoopSwitches = {{Gf, mW}};
31FR$RmDblExt = {ymb -> mb, ymc -> mc, ymdo -> md, yme -> me, ymm -> mmu, yms -> ms, ymt -> mt, ymtau -> mta, ymup -> mup};
32
33(* Vacuum expectation values *)
34
35M$vevs = {
36 {Phi[2], vev},
37 {PhiNP[2], vevNP}
38};
39
40(* Gauge groups *)
41
42M$GaugeGroups = {
43 U1Y == {
44 Abelian -> True,
45 CouplingConstant -> g1,
46 GaugeBoson -> B,
47 Charge -> Y
48 },
49 SU2L == {
50 Abelian -> False,
51 CouplingConstant -> gw,
52 GaugeBoson -> Wi,
53 StructureConstant -> Eps,
54 Representations -> {Ta, SU2D},
55 Definitions -> {
56 Ta[a_, b_, c_] -> PauliSigma[a, b, c]/2,
57 FSU2L[i_, j_, k_] :> I Eps[i, j, k]
58 }
59 },
60 SU3C == {
61 Abelian -> False,
62 CouplingConstant -> gs,
63 GaugeBoson -> G,
64 StructureConstant -> f,
65 Representations -> {T, Colour},
66 SymmetricTensor -> dSUN
67 }
68};
69
70(* Indices *)
71
72IndexRange[Index[SU2W]] = Unfold[Range[3]];
73IndexRange[Index[SU2D]] = Unfold[Range[2]];
74IndexRange[Index[Gluon]] = NoUnfold[Range[8]];
75IndexRange[Index[Colour]] = NoUnfold[Range[3]];
76IndexRange[Index[Generation]] = Range[3];
77IndexRange[Index[NeutrinoGeneration]] = NoUnfold[Range[5]];
78
79IndexStyle[SU2W, j];
80IndexStyle[SU2D, k];
81IndexStyle[Gluon, a];
82IndexStyle[Colour, m];
83IndexStyle[Generation, f];
84IndexStyle[NeutrinoGeneration, h];
85
86(* Interaction orders (as used by MG5) *)
87
88M$InteractionOrderHierarchy = {
89 {QCD, 1},
90 {NP, 1},
91 {QED, 2}
92};
93
94(* Parameters *)
95
96M$Parameters = {
97
98 (* External parameters SM *)
99
100 aEWM1 == {
101 ParameterType -> External,
102 BlockName -> SMINPUTS,
103 OrderBlock -> 1,
104 Value -> 127.9,
105 InteractionOrder -> {QED, -2},
106 Description -> "Inverse of the EW coupling constant at the Z pole"
107 },
108 Gf == {
109 ParameterType -> External,
110 BlockName -> SMINPUTS,
111 OrderBlock -> 2,
112 Value -> 1.16637*^-5,
113 InteractionOrder -> {QED, 2},
114 TeX -> Subscript[G, F],
115 Description -> "Fermi constant"
116 },
117 aS == {
118 ParameterType -> External,
119 BlockName -> SMINPUTS,
120 OrderBlock -> 3,
121 Value -> 0.1184,
122 InteractionOrder -> {QCD, 2},
123 TeX -> Subscript[\[Alpha], s],
124 Description -> "Strong coupling constant at the Z pole"
125 },
126 ymdo == {
127 ParameterType -> External,
128 BlockName -> YUKAWA,
129 OrderBlock -> 1,
130 Value -> 5.04*^-3,
131 Description -> "Down Yukawa mass"
132 },
133 ymup == {
134 ParameterType -> External,
135 BlockName -> YUKAWA,
136 OrderBlock -> 2,
137 Value -> 2.55*^-3,
138 Description -> "Up Yukawa mass"
139 },
140 yms == {
141 ParameterType -> External,
142 BlockName -> YUKAWA,
143 OrderBlock -> 3,
144 Value -> 0.101,
145 Description -> "Strange Yukawa mass"
146 },
147 ymc == {
148 ParameterType -> External,
149 BlockName -> YUKAWA,
150 OrderBlock -> 4,
151 Value -> 1.27,
152 Description -> "Charm Yukawa mass"
153 },
154 ymb == {
155 ParameterType -> External,
156 BlockName -> YUKAWA,
157 OrderBlock -> 5,
158 Value -> 4.7,
159 Description -> "Bottom Yukawa mass"
160 },
161 ymt == {
162 ParameterType -> External,
163 BlockName -> YUKAWA,
164 OrderBlock -> 6,
165 Value -> 172,
166 Description -> "Top Yukawa mass"
167 },
168 yme == {
169 ParameterType -> External,
170 BlockName -> YUKAWA,
171 OrderBlock -> 11,
172 Value -> 5.11*^-4,
173 Description -> "Electron Yukawa mass"
174 },
175 ymm == {
176 ParameterType -> External,
177 BlockName -> YUKAWA,
178 OrderBlock -> 13,
179 Value -> 0.10566,
180 Description -> "Muon Yukawa mass"
181 },
182 ymtau == {
183 ParameterType -> External,
184 BlockName -> YUKAWA,
185 OrderBlock -> 15,
186 Value -> 1.777,
187 Description -> "Tau Yukawa mass"
188 },
189 cabi == {
190 ParameterType -> External,
191 BlockName -> CKMBLOCK,
192 OrderBlock -> 1,
193 Value -> 0.227736,
194 TeX -> Subscript[\[Theta], c],
195 Description -> "Cabibbo angle"
196 },
197
198 (* External parameters pSPSS *)
199
200 Mmaj == {
201 ParameterType -> External,
202 BlockName -> pSPSS,
203 Value -> 20,
204 TeX -> Subscript[m, M],
205 Description -> "Heavy neutrino Majorana mass"
206 },
207 deltaM == {
208 ParameterType -> External,
209 BlockName -> pSPSS,
210 Value -> 1*^-12,
211 TeX -> Subscript[\[Delta], m],
212 Description -> "Heavy neutrino mass splitting"
213 },
214 theta1 == {
215 ParameterType -> External,
216 BlockName -> pSPSS,
217 Value -> 0,
218 InteractionOrder -> {NP, 1},
219 TeX -> Subscript[\[Theta], 1],
220 Description -> "Active sterile mixing 1"
221 },
222 theta2 == {
223 ParameterType -> External,
224 BlockName -> pSPSS,
225 Value -> 1*^-4,
226 InteractionOrder -> {NP, 1},
227 TeX -> Subscript[\[Theta], 2],
228 Description -> "Active sterile mixing 2"
229 },
230 theta3 == {
231 ParameterType -> External,
232 BlockName -> pSPSS,
233 Value -> 0,
234 InteractionOrder -> {NP, 1},
235 TeX -> Subscript[\[Theta], 3],
236 Description -> "Active sterile mixing 3"
237 },
238 damping == {
239 ParameterType -> External,
240 BlockName -> pSPSS,
241 Value -> 0,
242 Description -> "Damping parameter"
243 },
244
245 (* Internal Parameters pSPSS *)
246
247 thetasqr == {
248 ParameterType -> Internal,
249 Definitions -> {thetasqr -> theta1 * Conjugate[theta1] + theta2 * Conjugate[theta2] + theta3 * Conjugate[theta3]},
250 Description -> "Heavy neutrino Yukawa mass 1"
251 },
252 mn4 == {
253 ParameterType -> Internal,
254 Value -> Mmaj * (1 + thetasqr / 2) - deltaM / 2,
255 TeX -> Subscript[M, 4],
256 Description -> "n4 mass"
257 },
258 mn5 == {
259 ParameterType -> Internal,
260 Value -> Mmaj * (1 + thetasqr / 2) + deltaM / 2,
261 TeX -> Subscript[M, 5],
262 Description -> "n5 mass"
263 },
264 vevNP == { (* Necessary to get the correct interaction order for new Yukawas *)
265 ParameterType -> Internal,
266 Value -> 2 * mW * sw / ee / Sqrt[2],
267 InteractionOrder -> {NP, -1},
268 TeX -> v,
269 Description -> "Higgs vacuum expectation value for NP interactions"
270 },
271 yvn1 == {
272 ParameterType -> Internal,
273 Value -> Mmaj * theta1 / vevNP,
274 TeX -> Superscript[y, Subscript[\[Nu], 1]],
275 Description -> "Heavy neutrino Yukawa 1"
276 },
277 yvn2 == {
278 ParameterType -> Internal,
279 Value -> Mmaj * theta2 / vevNP,
280 TeX -> Superscript[y, Subscript[\[Nu], 2]],
281 Description -> "Heavy neutrino Yukawa 2"
282 },
283 yvn3 == {
284 ParameterType -> Internal,
285 Value -> Mmaj * theta3 / vevNP,
286 TeX -> Superscript[y, Subscript[\[Nu], 3]],
287 Description -> "Heavy neutrino Yukawa 3"
288 },
289 yvn == {
290 ParameterType -> Internal,
291 Indices -> {Index[Generation]},
292 Definitions -> {yvn[1] -> yvn1, yvn[2] -> yvn2, yvn[3] -> yvn3},
293 Description -> "Heavy neutrino Yukawas"
294 },
295 Un == {
296 ParameterType -> Internal,
297 Indices -> {Index[NeutrinoGeneration], Index[NeutrinoGeneration]},
298 ComplexParameter -> True,
299 Definitions -> {
300 Un[1, 1] -> 1 - theta1 * Conjugate[theta1] / 2,
301 Un[2, 1] -> - theta1 * Conjugate[theta2] / 2,
302 Un[3, 1] -> - theta1 * Conjugate[theta3] / 2,
303 Un[4, 1] -> 0,
304 Un[5, 1] -> - theta1,
305 Un[1, 2] -> - theta2 * Conjugate[theta1] / 2,
306 Un[2, 2] -> 1 - theta2 * Conjugate[theta2] / 2,
307 Un[3, 2] -> -theta2 * Conjugate[theta3] / 2,
308 Un[4, 2] -> 0,
309 Un[5, 2] -> - theta2,
310 Un[1, 3] -> - theta3 * Conjugate[theta1] / 2,
311 Un[2, 3] -> - theta3 * Conjugate[theta2] / 2,
312 Un[3, 3] -> 1 - theta3 * Conjugate[theta3] / 2,
313 Un[4, 3] -> 0,
314 Un[5, 3] -> - theta3,
315 Un[1, 4] -> -I * Conjugate[theta1] / Sqrt[2],
316 Un[2, 4] -> -I * Conjugate[theta2] / Sqrt[2],
317 Un[3, 4] -> -I * Conjugate[theta3] / Sqrt[2],
318 Un[4, 4] -> I / Sqrt[2],
319 Un[5, 4] -> -I * (1 - thetasqr / 2) / Sqrt[2],
320 Un[1, 5] -> Conjugate[theta1] / Sqrt[2],
321 Un[2, 5] -> Conjugate[theta2] / Sqrt[2],
322 Un[3, 5] -> Conjugate[theta3] / Sqrt[2],
323 Un[4, 5] -> 1 / Sqrt[2],
324 Un[5, 5] -> (1 - thetasqr / 2) / Sqrt[2]
325 },
326 Description -> "Neutrino 5x5 mixing matrix"
327 },
328 UnCL == {
329 ParameterType -> Internal,
330 Indices -> {Index[Generation], Index[NeutrinoGeneration]},
331 ComplexParameter -> True,
332 Definitions -> {UnCL[i_?NumericQ, j_?NumericQ] :> Un[i, j]},
333 Description -> "Charged lepton neutrino 3x5 mixing matrix"
334 },
335
336 (* Internal Parameters SM *)
337
338 aEW == {
339 ParameterType -> Internal,
340 Value -> 1/aEWM1,
341 InteractionOrder -> {QED, 2},
342 TeX -> Subscript[\[Alpha], EW],
343 Description -> "Electroweak coupling contant"
344 },
345 mW == {
346 ParameterType -> Internal,
347 Value -> Sqrt[mZ^2 / 2 + Sqrt[mZ^4 / 4 - Pi / Sqrt[2] * aEW / Gf * mZ^2]],
348 TeX -> Subscript[M, W],
349 Description -> "W mass"
350 },
351 sw2 == {
352 ParameterType -> Internal,
353 Value -> 1 - (mW / mZ)^2,
354 Description -> "Squared Sin of the Weinberg angle"
355 },
356 ee == {
357 ParameterType -> Internal,
358 Value -> Sqrt[4 Pi aEW],
359 InteractionOrder -> {QED, 1},
360 TeX -> e,
361 Description -> "Electric coupling constant"
362 },
363 cw == {
364 ParameterType -> Internal,
365 Value -> Sqrt[1 - sw2],
366 TeX -> Subscript[c, w],
367 Description -> "Cosine of the Weinberg angle"
368 },
369 sw == {
370 ParameterType -> Internal,
371 Value -> Sqrt[sw2],
372 TeX -> Subscript[s, w],
373 Description -> "Sine of the Weinberg angle"
374 },
375 gw == {
376 ParameterType -> Internal,
377 Definitions -> {gw -> ee/sw},
378 InteractionOrder -> {QED, 1},
379 TeX -> Subscript[g, w],
380 Description -> "Weak coupling constant at the Z pole"
381 },
382 g1 == {
383 ParameterType -> Internal,
384 Definitions -> {g1 -> ee/cw},
385 InteractionOrder -> {QED, 1},
386 TeX -> Subscript[g, 1],
387 Description -> "U(1)Y coupling constant at the Z pole"
388 },
389 gs == {
390 ParameterType -> Internal,
391 Value -> Sqrt[4 Pi aS],
392 InteractionOrder -> {QCD, 1},
393 TeX -> Subscript[g, s],
394 ParameterName -> G,
395 Description -> "Strong coupling constant at the Z pole"
396 },
397 vev == {
398 ParameterType -> Internal,
399 Value -> 2 * mW * sw / ee / Sqrt[2],
400 InteractionOrder -> {QED, -1},
401 TeX -> v,
402 Description -> "Higgs vacuum expectation value"
403 },
404 lam == {
405 ParameterType -> Internal,
406 Value -> MH^2 / (4 * vev^2),
407 InteractionOrder -> {QED, 2},
408 TeX -> \[Lambda],
409 Description -> "Higgs quartic coupling"
410 },
411 muH == {
412 ParameterType -> Internal,
413 Value -> Sqrt[2] Sqrt[lam] vev,
414 TeX -> \[Mu],
415 Description -> "Coefficient of the quadratic piece of the Higgs potential"
416 },
417 yl == {
418 ParameterType -> Internal,
419 Indices -> {Index[Generation], Index[Generation]},
420 Definitions -> {yl[i_?NumericQ, j_?NumericQ] :> 0 /; (i =!= j)},
421 Value -> {
422 yl[1, 1] -> yme / vev,
423 yl[2, 2] -> ymm / vev,
424 yl[3, 3] -> ymtau / vev
425 },
426 InteractionOrder -> {QED, 1},
427 ParameterName -> {
428 yl[1, 1] -> ye,
429 yl[2, 2] -> ym,
430 yl[3, 3] -> ytau
431 },
432 TeX -> Superscript[y, l],
433 Description -> "Lepton Yukawa couplings"
434 },
435 yu == {
436 ParameterType -> Internal,
437 Indices -> {Index[Generation], Index[Generation]},
438 Definitions -> {yu[i_?NumericQ, j_?NumericQ] :> 0 /; (i =!= j)},
439 Value -> {
440 yu[1, 1] -> ymup / vev,
441 yu[2, 2] -> ymc / vev,
442 yu[3, 3] -> ymt / vev
443 },
444 InteractionOrder -> {QED, 1},
445 ParameterName -> {
446 yu[1, 1] -> yup,
447 yu[2, 2] -> yc,
448 yu[3, 3] -> yt
449 },
450 TeX -> Superscript[y, u],
451 Description -> "Up-type Yukawa couplings"
452 },
453 yd == {
454 ParameterType -> Internal,
455 Indices -> {Index[Generation], Index[Generation]},
456 Definitions -> {yd[i_?NumericQ, j_?NumericQ] :> 0 /; (i =!= j)},
457 Value -> {
458 yd[1, 1] -> ymdo / vev,
459 yd[2, 2] -> yms / vev,
460 yd[3, 3] -> ymb / vev
461 },
462 InteractionOrder -> {QED, 1},
463 ParameterName -> {
464 yd[1, 1] -> ydo,
465 yd[2, 2] -> ys,
466 yd[3, 3] -> yb
467 },
468 TeX -> Superscript[y, d],
469 Description -> "Down-type Yukawa couplings"
470 },
471 CKM == { (* N. B. : only Cabibbo mixing! *)
472 ParameterType -> Internal,
473 Indices -> {Index[Generation], Index[Generation]},
474 Unitary -> True,
475 Value -> {
476 CKM[1, 1] -> Cos[cabi],
477 CKM[1, 2] -> Sin[cabi],
478 CKM[1, 3] -> 0,
479 CKM[2, 1] -> -Sin[cabi],
480 CKM[2, 2] -> Cos[cabi],
481 CKM[2, 3] -> 0,
482 CKM[3, 1] -> 0,
483 CKM[3, 2] -> 0,
484 CKM[3, 3] -> 1
485 },
486 TeX -> Superscript[V, CKM],
487 Description -> "CKM-Matrix"
488 }
489};
490
491(* Particle classes *)
492
493M$ClassesDescription = {
494
495 (* Gauge bosons: physical vector fields *)
496
497 V[1] == {
498 ClassName -> A,
499 SelfConjugate -> True,
500 Mass -> 0,
501 Width -> 0,
502 ParticleName -> "a",
503 PDG -> 22,
504 PropagatorLabel -> "a",
505 PropagatorType -> W,
506 PropagatorArrow -> None,
507 FullName -> "Photon"
508 },
509 V[2] == {
510 ClassName -> Z,
511 SelfConjugate -> True,
512 Mass -> {mZ, 91.1876},
513 Width -> {WZ, 2.4952},
514 ParticleName -> "Z",
515 PDG -> 23,
516 PropagatorLabel -> "Z",
517 PropagatorType -> Sine,
518 PropagatorArrow -> None,
519 FullName -> "Z"
520 },
521 V[3] == {
522 ClassName -> W,
523 SelfConjugate -> False,
524 Mass -> {mW, Internal},
525 Width -> {WW, 2.085},
526 ParticleName -> "W+",
527 AntiParticleName -> "W-",
528 QuantumNumbers -> {Q -> 1},
529 PDG -> 24,
530 PropagatorLabel -> "W",
531 PropagatorType -> Sine,
532 PropagatorArrow -> Forward,
533 FullName -> "W"
534 },
535 V[4] == {
536 ClassName -> G,
537 SelfConjugate -> True,
538 Indices -> {Index[Gluon]},
539 Mass -> 0,
540 Width -> 0,
541 ParticleName -> "g",
542 PDG -> 21,
543 PropagatorLabel -> "G",
544 PropagatorType -> C,
545 PropagatorArrow -> None,
546 FullName -> "G"
547 },
548
549 (* Ghosts: related to physical gauge bosons *)
550
551 U[1] == {
552 ClassName -> ghA,
553 SelfConjugate -> False,
554 Ghost -> A,
555 QuantumNumbers -> {GhostNumber -> 1},
556 Mass -> 0,
557 Width -> 0,
558 PropagatorLabel -> "uA",
559 PropagatorType -> GhostDash,
560 PropagatorArrow -> Forward
561 },
562 U[2] == {
563 ClassName -> ghZ,
564 SelfConjugate -> False,
565 Ghost -> Z,
566 QuantumNumbers -> {GhostNumber -> 1},
567 Mass -> {mZ, 91.1876},
568 Width -> {WZ, 2.4952},
569 PropagatorLabel -> "uZ",
570 PropagatorType -> GhostDash,
571 PropagatorArrow -> Forward
572 },
573 U[31] == {
574 ClassName -> ghWp,
575 SelfConjugate -> False,
576 Ghost -> W,
577 QuantumNumbers -> {GhostNumber -> 1, Q -> 1},
578 Mass -> {mW, Internal},
579 Width -> {WW, 2.085},
580 PropagatorLabel -> "uWp",
581 PropagatorType -> GhostDash,
582 PropagatorArrow -> Forward
583 },
584 U[32] == {
585 ClassName -> ghWm,
586 SelfConjugate -> False,
587 Ghost -> Wbar,
588 QuantumNumbers -> {GhostNumber -> 1, Q -> -1},
589 Mass -> {mW, Internal},
590 Width -> {WW, 2.085},
591 PropagatorLabel -> "uWm",
592 PropagatorType -> GhostDash,
593 PropagatorArrow -> Forward
594 },
595 U[4] == {
596 ClassName -> ghG,
597 SelfConjugate -> False,
598 Indices -> {Index[Gluon]},
599 Ghost -> G,
600 PDG -> 82,
601 QuantumNumbers -> {GhostNumber -> 1},
602 Mass -> 0,
603 Width -> 0,
604 PropagatorLabel -> "uG",
605 PropagatorType -> GhostDash,
606 PropagatorArrow -> Forward
607 },
608
609 (* Gauge bosons: unphysical vector fields *)
610
611 V[11] == {
612 ClassName -> B,
613 Unphysical -> True,
614 SelfConjugate -> True,
615 Definitions -> {B[mu_] -> -sw Z[mu] + cw A[mu]}
616 },
617 V[12] == {
618 ClassName -> Wi,
619 Unphysical -> True,
620 SelfConjugate -> True,
621 Indices -> {Index[SU2W]},
622 FlavorIndex -> SU2W,
623 Definitions -> {
624 Wi[mu_, 1] -> (Wbar[mu] + W[mu]) / Sqrt[2],
625 Wi[mu_, 2] -> (Wbar[mu] - W[mu]) / (I * Sqrt[2]),
626 Wi[mu_, 3] -> cw Z[mu] + sw A[mu]
627 }
628 },
629
630 (* Ghosts: related to unphysical gauge bosons *)
631
632 U[11] == {
633 ClassName -> ghB,
634 Unphysical -> True,
635 SelfConjugate -> False,
636 Ghost -> B,
637 Definitions -> {ghB -> -sw ghZ + cw ghA}
638 },
639 U[12] == {
640 ClassName -> ghWi,
641 Unphysical -> True,
642 SelfConjugate -> False,
643 Ghost -> Wi,
644 Indices -> {Index[SU2W]},
645 FlavorIndex -> SU2W,
646 Definitions -> {
647 ghWi[1] -> (ghWp + ghWm) / Sqrt[2],
648 ghWi[2] -> (ghWm - ghWp) / (I * Sqrt[2]),
649 ghWi[3] -> cw ghZ + sw ghA
650 }
651 },
652
653 (* Fermions: physical fields *)
654
655 F[1] == {
656 ClassName -> vl,
657 ClassMembers -> {ve, vm, vt},
658 Indices -> {Index[Generation]},
659 FlavorIndex -> Generation,
660 SelfConjugate -> False,
661 Mass -> 0,
662 Width -> 0,
663 PropagatorLabel -> {"v", "ve", "vm", "vt"},
664 PropagatorType -> S,
665 PropagatorArrow -> Forward,
666 PDG -> {12, 14, 16},
667 ParticleName -> {"ve", "vm", "vt"},
668 AntiParticleName -> {"ve~", "vm~", "vt~"},
669 FullName -> {"Electron-neutrino", "Muon-neutrino", "Tau-neutrino"}
670 },
671 F[2] == {
672 ClassName -> l,
673 ClassMembers -> {e, mu, ta},
674 Indices -> {Index[Generation]},
675 FlavorIndex -> Generation,
676 SelfConjugate -> False,
677 Mass -> {Ml, {me, 5.11*^-4}, {mmu, 0.10566}, {mta, 1.777}},
678 Width -> 0,
679 QuantumNumbers -> {Q -> -1},
680 PropagatorLabel -> {"l", "e", "mu", "ta"},
681 PropagatorType -> Straight,
682 PropagatorArrow -> Forward,
683 PDG -> {11, 13, 15},
684 ParticleName -> {"e-", "mu-", "ta-"},
685 AntiParticleName -> {"e+", "mu+", "ta+"},
686 FullName -> {"Electron", "Muon", "Tau"}
687 },
688 F[3] == {
689 ClassName -> uq,
690 ClassMembers -> {u, c, t},
691 Indices -> {Index[Generation], Index[Colour]},
692 FlavorIndex -> Generation,
693 SelfConjugate -> False,
694 Mass -> {Mu, {mup, 2.55*^-3}, {mc, 1.27}, {mt, 172}},
695 Width -> {0, 0, {WT, 1.50833649}},
696 QuantumNumbers -> {Q -> 2/3},
697 PropagatorLabel -> {"uq", "u", "c", "t"},
698 PropagatorType -> Straight,
699 PropagatorArrow -> Forward,
700 PDG -> {2, 4, 6},
701 ParticleName -> {"u", "c", "t"},
702 AntiParticleName -> {"u~", "c~", "t~"},
703 FullName -> {"u-quark", "c-quark", "t-quark"}
704 },
705 F[4] == {
706 ClassName -> dq,
707 ClassMembers -> {d, s, b},
708 Indices -> {Index[Generation], Index[Colour]},
709 FlavorIndex -> Generation,
710 SelfConjugate -> False,
711 Mass -> {Md, {md, 5.04*^-3}, {ms, 0.101}, {mb, 4.7}},
712 Width -> 0,
713 QuantumNumbers -> {Q -> -1/3},
714 PropagatorLabel -> {"dq", "d", "s", "b"},
715 PropagatorType -> Straight,
716 PropagatorArrow -> Forward,
717 PDG -> {1, 3, 5},
718 ParticleName -> {"d", "s", "b"},
719 AntiParticleName -> {"d~", "s~", "b~"},
720 FullName -> {"d-quark", "s-quark", "b-quark"}
721 },
722
723 (* Fermions: physical fields of the pSPSS *)
724
725 F[5] == {
726 ClassName -> n4,
727 SelfConjugate -> True,
728 Mass -> {mn4, Internal},
729 Width -> {Wn4, 1*^-5},
730 PropagatorLabel -> {"n4"},
731 PropagatorType -> Straight,
732 PropagatorArrow -> None,
733 PDG -> 8000011,
734 ParticleName -> {"n4"},
735 FullName -> {"Heavy neutrino n4"}
736 },
737 F[6] == {
738 ClassName -> n5,
739 SelfConjugate -> True,
740 Mass -> {mn5, Internal},
741 Width -> {Wn5, 1*^-5},
742 PropagatorLabel -> {"n5"},
743 PropagatorType -> Straight,
744 PropagatorArrow -> None,
745 PDG -> 8000012,
746 ParticleName -> {"n5"},
747 FullName -> {"Heavy neutrino n5"}
748 },
749
750 (* Fermions: unphysical fields of the pSPSS *)
751
752 F[8] == {
753 ClassName -> nL,
754 Unphysical -> True,
755 Indices -> {Index[NeutrinoGeneration]},
756 FlavorIndex -> NeutrinoGeneration,
757 SelfConjugate -> False,
758 Definitions -> {
759 nL[sp1_, 1] :> vl[sp1, 1]*Sqrt[2],
760 nL[sp1_, 2] :> vl[sp1, 2]*Sqrt[2],
761 nL[sp1_, 3] :> vl[sp1, 3]*Sqrt[2],
762 nL[sp1_, 4] :> n4[sp1],
763 nL[sp1_, 5] :> n5[sp1]
764 }
765 },
766 F[9] == {
767 ClassName -> N1L,
768 Unphysical -> True,
769 SelfConjugate -> True,
770 Definitions -> {
771 N1L[sp1_] :> Module[{sp2, hh}, ProjM[sp1, sp2] Un[4, hh] nL[sp2, hh]]
772 }
773 },
774 F[10] == {
775 ClassName -> N2L,
776 Unphysical -> True,
777 SelfConjugate -> True,
778 Definitions -> {
779 N2L[sp1_] :> Module[{sp2, hh}, ProjM[sp1, sp2] Un[5, hh] nL[sp2, hh]]
780 }
781 },
782 F[11] == {
783 ClassName -> LL,
784 Unphysical -> True,
785 Indices -> {Index[SU2D], Index[Generation]},
786 FlavorIndex -> SU2D,
787 SelfConjugate -> False,
788 QuantumNumbers -> {Y -> -1/2},
789 Definitions -> {
790 LL[sp1_, 1, ff_] :> Module[{sp2, hh}, ProjM[sp1, sp2] UnCL[ff, hh] nL[sp2, hh]],
791 LL[sp1_, 2, ff_] :> Module[{sp2}, ProjM[sp1, sp2] l[sp2, ff]]
792 }
793 },
794
795 (* Fermions: unphysical fields *)
796
797 F[12] == {
798 ClassName -> lR,
799 Unphysical -> True,
800 Indices -> {Index[Generation]},
801 FlavorIndex -> Generation,
802 SelfConjugate -> False,
803 QuantumNumbers -> {Y -> -1},
804 Definitions -> {
805 lR[sp1_, ff_] :> Module[{sp2}, ProjP[sp1, sp2] l[sp2, ff]]
806 }
807 },
808 F[13] == {
809 ClassName -> QL,
810 Unphysical -> True,
811 Indices -> {Index[SU2D], Index[Generation], Index[Colour]},
812 FlavorIndex -> SU2D,
813 SelfConjugate -> False,
814 QuantumNumbers -> {Y -> 1/6},
815 Definitions -> {
816 QL[sp1_, 1, ff_, cc_] :> Module[{sp2}, ProjM[sp1, sp2] uq[sp2, ff, cc]],
817 QL[sp1_, 2, ff_, cc_] :> Module[{sp2, ff2}, CKM[ff, ff2] ProjM[sp1, sp2] dq[sp2, ff2, cc]] }
818 },
819 F[14] == {
820 ClassName -> uR,
821 Unphysical -> True,
822 Indices -> {Index[Generation], Index[Colour]},
823 FlavorIndex -> Generation,
824 SelfConjugate -> False,
825 QuantumNumbers -> {Y -> 2/3},
826 Definitions -> {
827 uR[sp1_, ff_, cc_] :> Module[{sp2}, ProjP[sp1, sp2] uq[sp2, ff, cc]]
828 }
829 },
830 F[15] == {
831 ClassName -> dR,
832 Unphysical -> True,
833 Indices -> {Index[Generation], Index[Colour]},
834 FlavorIndex -> Generation,
835 SelfConjugate -> False,
836 QuantumNumbers -> {Y -> -1/3},
837 Definitions -> {
838 dR[sp1_, ff_, cc_] :> Module[{sp2}, ProjP[sp1, sp2] dq[sp2, ff, cc]]
839 }
840 },
841
842 (* Higgs: physical scalars *)
843
844 S[1] == {
845 ClassName -> H,
846 SelfConjugate -> True,
847 Mass -> {MH, 125},
848 Width -> {WH, 0.00407},
849 PropagatorLabel -> "H",
850 PropagatorType -> D,
851 PropagatorArrow -> None,
852 PDG -> 25,
853 ParticleName -> "H",
854 FullName -> "H"
855 },
856
857 (* Higgs: physical scalars *)
858
859 S[2] == {
860 ClassName -> G0,
861 SelfConjugate -> True,
862 Goldstone -> Z,
863 Mass -> {mZ, 91.1876},
864 Width -> {WZ, 2.4952},
865 PropagatorLabel -> "Go",
866 PropagatorType -> D,
867 PropagatorArrow -> None,
868 PDG -> 250,
869 ParticleName -> "G0",
870 FullName -> "G0"
871 },
872 S[3] == {
873 ClassName -> GP,
874 SelfConjugate -> False,
875 Goldstone -> W,
876 Mass -> {mW, Internal},
877 QuantumNumbers -> {Q -> 1},
878 Width -> {WW, 2.085},
879 PropagatorLabel -> "GP",
880 PropagatorType -> D,
881 PropagatorArrow -> None,
882 PDG -> 251,
883 ParticleName -> "G+",
884 AntiParticleName -> "G-",
885 FullName -> "GP"
886 },
887
888 (* Higgs: unphysical scalars *)
889
890 S[11] == {
891 ClassName -> Phi,
892 Unphysical -> True,
893 Indices -> {Index[SU2D]},
894 FlavorIndex -> SU2D,
895 SelfConjugate -> False,
896 QuantumNumbers -> {Y -> 1/2},
897 Definitions -> {
898 Phi[1] -> -I GP,
899 Phi[2] -> vev + (H + I G0) / Sqrt[2]
900 }
901 },
902
903 (* pSPSS Higgs necessary to get the correct interaction order for new Yukawas *)
904
905 S[12] == {
906 ClassName -> PhiNP,
907 Unphysical -> True,
908 Indices -> {Index[SU2D]},
909 FlavorIndex -> SU2D,
910 SelfConjugate -> False,
911 QuantumNumbers -> {Y -> 1/2},
912 Definitions -> {
913 PhiNP[1] -> -I GP,
914 PhiNP[2] -> vevNP + (H + I G0) / Sqrt[2]
915 }
916 }
917};
918
919(* Gauge Parameters (FeynArts) *)
920
921GaugeXi[V[1]] = GaugeXi[A];
922GaugeXi[V[2]] = GaugeXi[Z];
923GaugeXi[V[3]] = GaugeXi[W];
924GaugeXi[V[4]] = GaugeXi[G];
925GaugeXi[S[1]] = 1;
926GaugeXi[S[2]] = GaugeXi[Z];
927GaugeXi[S[3]] = GaugeXi[W];
928GaugeXi[U[1]] = GaugeXi[A];
929GaugeXi[U[2]] = GaugeXi[Z];
930GaugeXi[U[4]] = GaugeXi[G];
931GaugeXi[U[31]] = GaugeXi[W];
932GaugeXi[U[32]] = GaugeXi[W];
933
934(* Helper function *)
935
936RemoveHigherOrder[Lag_] := Block[{tmp, epsilon, x1, x2, x3},
937 tmp = Lag // ExpandIndices // OptimizeIndex;
938 tmp = Series[tmp /. {
939 theta1 -> epsilon x1,
940 theta2 -> epsilon x2,
941 theta3 -> epsilon x3
942 }, {epsilon, 0, 2}];
943 tmp /. {
944 x1 -> theta1 / epsilon,
945 x2 -> theta2 / epsilon,
946 x3 -> theta3 / epsilon
947 } // Normal
948];
949
950(* Lagrangian *)
951
952LGauge := Block[{mu, nu, ii, aa},
953 - ExpandIndices[
954 1/4 FS[B, mu, nu] FS[B, mu, nu] +
955 1/4 FS[Wi, mu, nu, ii] FS[Wi, mu, nu, ii] +
956 1/4 FS[G, mu, nu, aa] FS[G, mu, nu, aa],
957 FlavorExpand -> SU2W
958 ]
959];
960
961preLFermions := Block[{mu},
962 I * ExpandIndices[
963 QLbar.Ga[mu].DC[QL, mu] +
964 LLbar.Ga[mu].DC[LL, mu] +
965 N1Lbar.Ga[mu].del[N1L, mu] +
966 N2Lbar.Ga[mu].del[N2L, mu] +
967 uRbar.Ga[mu].DC[uR, mu] +
968 dRbar.Ga[mu].DC[dR, mu] +
969 lRbar.Ga[mu].DC[lR, mu],
970 FlavorExpand -> {SU2W, SU2D, NeutrinoGeneration}
971 ] /. {
972 CKM[a_, b_] Conjugate[CKM[a_, c_]] -> IndexDelta[b, c],
973 CKM[b_, a_] Conjugate[CKM[c_, a_]] -> IndexDelta[b, c]
974 }
975];
976LFermions := LFermions = RemoveHigherOrder[preLFermions];
977
978LHiggs := Block[{ii, mu, feynmangaugerules},
979 feynmangaugerules = If[Not[FeynmanGauge], {G0|GP|GPbar -> 0}, {}];
980 ExpandIndices[
981 DC[Phibar[ii], mu] DC[Phi[ii], mu] +
982 muH^2 Phibar[ii] Phi[ii] -
983 lam Phibar[ii] Phi[ii] Phibar[jj] Phi[jj],
984 FlavorExpand -> {SU2D, SU2W}
985 ] /. feynmangaugerules
986];
987
988LYukawa := Block[{sp, ii, jj, cc, ff1, ff2, ff3, yuk, feynmangaugerules},
989 feynmangaugerules = If[Not[FeynmanGauge], {G0|GP|GPbar -> 0}, {}];
990 yuk = - ExpandIndices[
991 yd[ff2, ff3] CKM[ff1, ff2] QLbar[sp, ii, ff1, cc].dR [sp, ff3, cc] Phi[ii] +
992 yl[ff1, ff3] LLbar[sp, ii, ff1].lR [sp, ff3] Phi[ii] +
993 yu[ff1, ff2] QLbar[sp, ii, ff1, cc].uR [sp, ff2, cc] Phibar[jj] Eps[ii, jj],
994 FlavorExpand -> SU2D
995 ];
996 yuk = yuk /. {
997 CKM[a_, b_] Conjugate[CKM[a_, c_]] -> IndexDelta[b, c],
998 CKM[b_, a_] Conjugate[CKM[c_, a_]] -> IndexDelta[b, c]
999 };
1000 yuk + HC[yuk] /. feynmangaugerules
1001];
1002
1003preLNP := Block[{sp1, ff1, ii, jj, yuk, feynmangaugerules},
1004 feynmangaugerules = If[Not[FeynmanGauge], {G0|GP|GPbar -> 0}, {}];
1005 yuk = - ExpandIndices[
1006 Mmaj CC[N1Lbar[sp1]].N2L[sp1] +
1007 yvn[ff1] (CC[N1Lbar[sp1]].LL[sp1, ii, ff1] PhiNPbar[jj] Eps[ii, jj]),
1008 FlavorExpand -> {SU2D, NeutrinoGeneration}
1009 ];
1010 yuk + HC[yuk] /. feynmangaugerules
1011];
1012LNP := LNP = RemoveHigherOrder[preLNP];
1013
1014LGhost := Block[{LGh1, LGhw, LGhs, LGhphi, mu, generators, gh, ghbar, Vectorize, phi1, phi2, togoldstones, doublet, doublet0},
1015 (* Pure gauge piece *)
1016 LGh1 = - ghBbar.del[DC[ghB, mu], mu];
1017 LGhw = - ghWibar[ii].del[DC[ghWi[ii], mu], mu];
1018 LGhs = - ghGbar[ii].del[DC[ghG[ii], mu], mu];
1019 (* Scalar pieces: see Peskin pages 739-742 *)
1020 gh = {ghB, ghWi[1], ghWi[2], ghWi[3]};
1021 ghbar = {ghBbar, ghWibar[1], ghWibar[2], ghWibar[3]};
1022 generators = {
1023 -I g1 IdentityMatrix[2] / 2,
1024 -I gw PauliSigma[1] / 2,
1025 -I gw PauliSigma[2] / 2,
1026 -I gw PauliSigma[3] / 2
1027 };
1028 (* phi1 and phi2 are the real degrees of freedom of GP *)
1029 doublet = Expand[{-(I phi1 + phi2) / Sqrt[2], Phi[2]} /. MR$Definitions /. vev -> 0];
1030 doublet0 = {0, vev};
1031 (* Vectorize transforms a doublet in a vector in the phi-basis, i.e. the basis of real degrees of freedom *)
1032 Vectorize[{a_, b_}] := Simplify[{
1033 Sqrt[2] Re[Expand[a]],
1034 Sqrt[2] Im[Expand[a]],
1035 Sqrt[2] Re[Expand[b]],
1036 Sqrt[2] Im[Expand[b]]
1037 } /. {Im[_] -> 0, Re[num_] -> num}];
1038 togoldstones := {
1039 phi1 -> (GPbar + GP) / Sqrt[2],
1040 phi2 -> (GPbar - GP) / (I Sqrt[2])
1041 };
1042 LGhphi = Plus@@Flatten[Table[-ghbar[[kkk]].gh[[lll]] Vectorize[generators[[kkk]].doublet0].Vectorize[generators[[lll]].(doublet + doublet0)], {kkk, 4}, {lll, 4}]] /. togoldstones;
1043 ExpandIndices[LGhs + If[FeynmanGauge, LGh1 + LGhw + LGhphi, 0], FlavorExpand -> SU2W]
1044];
1045
1046LSM := LGauge + LFermions + LHiggs + LYukawa + LGhost; (* contains sterile neutrino kinetic terms *)
1047LpSPSS := LSM + LNP;