SchoolKias/FeynRules: susyqcd_dirac.fr

(* ********************************************************* *)
(* *****                                               ***** *)
(* *****  FeynRules model file: SUSY-QCD               ***** *)
(* *****  Author: B. Fuks                              ***** *)
(* *****                                               ***** *)
(* ********************************************************* *)


(* ************************** *)
(* *****  Information   ***** *)
(* ************************** *)
M$ModelName = "SUSYQCD";

M$Information = {
  Authors      -> {"Benjamin Fuks"}, 
  Date         ->  "24.10.11",
  Version      ->  "1.0.0",
  Institutions -> {"IPHC Strasbourg / U. of Strasbourg"},
  Emails       -> {"benjamin.fuks@iphc.cnrs.fr"}
};


(* ************************** *)
(* *****    Indices     ***** *)
(* ************************** *)
IndexRange[Index[Gluon ]] = NoUnfold[Range[8]]; IndexStyle[Gluon,  a];  
IndexRange[Index[Colour]] = NoUnfold[Range[3]]; IndexStyle[Colour, m]; 
IndexRange[Index[Gen   ]] = Range[3];           IndexStyle[Gen,    f];

(* ************************** *)
(* *****  Gauge groups  ***** *)
(* ************************** *)
M$GaugeGroups = {
  SU3C == { 
    Abelian           -> False, 
    GaugeBoson        -> G,
    CouplingConstant  -> gs, 
    StructureConstant -> f,
    Representations   -> {T,Colour} }
};

(* ************************** *)
(* *****     Fields     ***** *)
(* ************************** *)
M$ClassesDescription = {
  (* Gluon field *)
  V[1] == { 
    ClassName       -> G, 
    SelfConjugate   -> True, 
    Indices         -> {Index[Gluon]}, 
    Mass            -> 0, 
    Width           -> 0,
    PDG             -> 21
  },

  (* gluino *)
  F[1] == {
    ClassName        -> go,
    SelfConjugate    -> True,
    Indices          -> {Index[Gluon]},
    Mass             -> {Mgo,500},
    Width            -> {Wgo,10},
    PDG              -> 1000021
  },

  (* up-type quarks *)
  F[2] == {
    ClassName        -> uq,
    SelfConjugate    -> False,
    Indices          -> {Index[Gen], Index[Colour]},
    FlavorIndex      -> Gen,
    QuantumNumbers   -> {Q -> 2/3},
    ClassMembers     -> {u, c, t},
    Mass             -> {Mu, {MU,2.55*^-3}, {MC,1.42}, {MT,172}},
    Width            -> {0, 0, {WT, 1.50833649}},
    PDG              -> {2, 4, 6}
  },

  (* left-handed up-type squarks *)
  S[1] == {
    ClassName        -> sqL,
    SelfConjugate    -> False,
    Indices          -> {Index[Gen],Index[Colour]},
    FlavorIndex      -> Gen,
    QuantumNumbers   -> {Q -> 2/3},
    ClassMembers     -> {suL, scL, stL},
    Mass             -> {MsqL, {MsuL,300}, {MscL,300}, {MstL,300}}, 
    Width            -> {{WsuL,5}, {WscL,5}, {WstL,5}},
    PDG              -> {1000002, 1000004, 1000006}
  },

  (* right-handed up-type squarks *)
  S[2] == {
    ClassName        -> sqR,
    SelfConjugate    -> False,
    Indices          -> {Index[Gen],Index[Colour]},
    FlavorIndex      -> Gen,
    QuantumNumbers   -> {Q -> 2/3},
    ClassMembers     -> {suR, scR, stR},
    Mass             -> {MsqR, {MsuR,300}, {MscR,300}, {MstR,300}}, 
    Width            -> {{WsuR,5}, {WscR,5}, {WstR,5}},
    PDG              -> {2000002, 2000004, 2000006}
  }
};

(* ************************** *)
(* *****   Parameters   ***** *)
(* ************************** *)
M$Parameters = {
  aS    == { 
    ParameterType    -> External,
    Value            -> 0.1184,
    InteractionOrder -> {QCD, 2}
  },
  gs == {
    ParameterType    -> Internal,
    Value            -> Sqrt[4 Pi aS],
    InteractionOrder -> {QCD, 1},
    ParameterName    -> G
  }
};

(* ************************** *)
(* *****   Lagrangian   ***** *)
(* ************************** *)
LVector := -1/4 FS[G,mu,nu,a] FS[G,mu,nu,a] +
            I/2 Ga[mu,s1,s2] gobar[s1,a].DC[go[s2,a],mu] -
            1/2 Mgo gobar[s1,a].go[s1,a];

Lkin := DC[sqLbar[cc,ff],mu] DC[sqL[cc,ff],mu] +
       DC[sqRbar[cc,ff],mu] DC[sqR[cc,ff],mu] +
       I Ga[mu,s1,s2] uqbar[s1,ff,cc].DC[uq[s2,ff,cc],mu] -
       Mu[ff] uqbar[s1,ff,cc].uq[s1,ff,cc] -
       MsqL[ff]^2 sqLbar[ff,cc] sqL[ff,cc] -
       MsqR[ff]^2 sqRbar[ff,cc] sqR[ff,cc];

LD := -1/2 gs^2 *
       (sqRbar[ff1,cc1] T[a,cc1,cc2] sqR[ff1,cc2] - 
        sqLbar[ff1,cc1] T[a,cc1,cc2] sqL[ff1,cc2]) * 
       (sqRbar[ff2,cc3] T[a,cc3,cc4] sqR[ff2,cc4] - 
        sqLbar[ff2,cc3] T[a,cc3,cc4] sqL[ff2,cc4]);

Lgosqq :=  Sqrt[2] gs ProjM[s1,s2] * ( 
    - sqLbar[ff, cc1] T[a,cc1,cc2] gobar[s1,a].uq[s2,ff,cc2] + 
      uqbar[s1,ff,cc1].go[s2,a] T[a,cc1,cc2] sqR[ff,cc2]);

LMatter := Lkin + LD + Lgosqq + HC[Lgosqq];

Lagr := LVector + LMatter;